遊戲《魔獸世界》中，使用輔助的工具能夠提升我們自身的戰鬥力。很多玩家並不瞭解，那麼宏命令從入門到精通怎麼弄？一起來看宏命令教程從入門到精通吧。
wow宏命令教程從入門到精通
問題：
魔獸世界宏命令從入門到精通怎麼弄？
答案：
正式服
use使用，cast施放。過去非技能用use技能用cast，現在他們功能是一樣的，即便是長久的習慣和認知問題現在也應改過來，因為use 3個字節，中文命令“施放”2個字節，適用於精簡語法，宏瘦身。
use有選鼠標選擇功能，極少情況需要用到，如13和14裝備欄位施放飾品宏(6和15腰帶披風又可以用“施放”)，懷舊服主副手上毒宏，選礦或開鎖需要用use。
目標判定(僅有這3種目標判定，均可加no反向判定)
harm敵方， help友方， exists存在(敵我通用技能用存在判斷)
目標狀態判定僅能判斷是否死亡
比如對活着的敵友或存在的目標施放加入nodead;復活技能判定加入dead
對敵施放用harm,nodead;對友施放用help,nodead
不加nodead會導致如鼠標指向一個死亡目標，仍然對此用技能一直提示錯誤目標，加入後就會忽略他執行下面的命令。例如組合鍵對焦點施放，焦點死亡判定不成立>往下鼠標指向>再往下當前目標
只能對敵人施放的技能用harm，友方用help，不要用exists，導致問題同上，exists用於敵我均能施放的技能，神聖視野，神聖震擊
環境和狀態判定(均可加no反向判定，坐騎宏，環境，變形，姿態，潛行狀態)
indoors室內，outdoors室外，swimming水裏，flyable可以飛，combat戰鬥，stealth潛行
group隊伍(用於懷舊服整合技能簡化技能數量，隊伍狀態豹羣取代獵豹，羣體上智耐祝福取代單體，也可自己DIY隊伍和單人情況使用不同技能)
form姿態(form比廣泛使用的stance更節省字符應該改用，他們功能是完全一樣的;常用範例form:X姿態X，form:X/X姿態X或X，noform沒有姿態，noform:X沒有姿態X，noform:X/X沒有姿態X或X)
[talent:X/X]命令判定當前天賦，實現2個不同時點的天賦之間切換，可以是1天賦1技能之間，也可是2個天賦之間，只要不會衝突
需要説明[PVPtalent:X/X]在8.0大部分失效了不能用了!天賦都混合在一起了，簡單説現在PVP技能只能添加一個切換，後面有大量例子
[spec:X]判定當前專精，比如戰士[spec:1]是武器，2是狂暴，3是防禦;把三系的多個宏使用該判定整合為一個宏，這個命令在宏整合非常重要
舉例整合：三系基礎技能自動切換，盾猛自動檔加開關
#showtooltip
/施放 [spec:1,@mouseover,harm,nodead][spec:1]致死打擊;[spec:2,@mouseover,harm,nodead][spec:2]嗜血;[mod,@mouseover,harm,nodead][mod]盾牌猛擊;[@mouseover,harm,nodead][]盾牌猛擊
/stopmacro [mod]
/施放 無視苦痛
/施放 盾牌格擋
簡單講就是這樣，因排除法最後一個天賦不用加命令，下面這個宏沒有任何判定也就拾取了做宏的意義
/施放 [spec:1]奧術衝擊;[spec:2]火球術;寒冰箭
@目標判定，player自己，pet寵物，focus焦點，target目標，targettarget目標的目標，mouseover鼠標指向，cursor光標位置，form姿態(相比stance少2字符)，party1隊伍框架1，arena1競技場敵方框架1，partypet1隊伍框架1的寵物，arenapet1競技場敵方框架1的寵物
注意：focus焦點，敵方死亡自動取消焦點，仍可以再次焦點屍體，友方死亡不會取消焦點，故對敵焦點施法宏不在加入nodead判定，例[mod,@focus,harm]
@等於target=
@XXXX 和target=XXXX 是一個意思(目標等於XXXX)，所以用前面的@節約6個字符，例如@focus，@player，@pet比較target=focus，~=player，~=pet
注意:“@名字”“target=名字”這兩個命令都只能選擇隊伍中的玩家，如果要選擇敵方玩家和NPC用“/目標 名字”
@mouseover和@Cursor 這兩者適用於兩者不同情況，他們是不一樣的!
@mouseover 適用於鼠標指向施放技能
@cursor 適用於地板技能光標位置施放
@pet目標寵物適用於需要了解目標狀態施法的技能，比如獵人復活死亡的寵物
目標寵物@pet能判斷自己的寵物，@targetpet能判斷隊友的寵物或@partypet1隊伍框架1玩家的寵物，@arenapet1競技場框架1位置敵方玩家的寵物。不能判定非組隊的友方和場外敵方的寵物。就像某些技能只能對隊友施放(吐槽懷舊服牧師盾不能給隊友之外，不識誰家犬也就算了，套個盾也要認識邏輯何在?)
;分號，代表完整命令段落的結束，需要開啟下一個段落;用來分割，用於開始一個新的技能，同一個技能不需要;分號，最後一個技能的末尾不需要
特殊情況如寶寶攻擊/petattack [mod,@focus,harm][@mouseover,harm,nodead];末端需要加分號或[]才會執行無指向的時候攻擊當前目標(這裏;分號=[]括號，區別是字節少1個)(帶有技能名的情況;分號≠[]括號)
同一個技能，多次[目標判斷]只需要一個名字，一個分號;例子
/施放 [mod,@focus,harm][@mouseover,harm,nodead][]破膽怒吼
空格，做宏應當用最優化的邏輯節省儘量多的字符，只有起始命令如/cast /use #showtooltip 等等加一空格才能生效，後續命令均是,和;來斷句
每個[]都代表一個完整的判定，他是從上往下從左往右按順匹配條件執行的，條件一般是組合鍵，敵我身份存活情況，天賦分辨姿態分辨
所有的“/命令”後面都可以加[]來添加條件，只要想得到且能解決問題
一些例子
/施放 [combat]狂暴姿態;戰鬥姿態(戰鬥中切換狂暴姿態，非戰鬥戰鬥姿態，懷舊服)
/施放 [pet]黑暗突變;亡者復生(沒寶寶招寶寶，有寶寶變身)
/eq [nomod]盾牌名字;(eq是equip的縮寫，沒按組合鍵裝備盾牌)
/equipslot [nomod]16 單手武器(沒按組合鍵裝備16部位的單手武器)
/stopmacro [mod](按組合鍵停止該命令後面的命令)
/cancelform [mod](按組合鍵取消形態)
/cancelaura [mod]技能(按組合鍵取消技能)
/cleartarget [help][dead](不是敵人或死亡取消目標，如果剛才的2個分開的條件是在一個括號內[noharm,dead]就需要同時達成所有條件才執行命令)
按組合寵物移動，不按組合鍵施放技能，避免衝突
/petmoveto [mod]
/施放 [nomod]技能
[]括號內是判定條件，空括號是無判定即對目標施放，更簡潔
/施放 [@mouseover,harm,nodead][]吸血鬼之觸
/施放 [@mouseover,harm,nodead]吸血鬼之觸;吸血鬼之觸
[]有需要也可以加入組合鍵和目標判定，單方面的技能沒必要在加判定，敵我通用技能看情況加判定，例子：
/施放 [@mouseover,harm,nodead][harm,nodead]吸血鬼之觸(無意義)
/施放 [@mouseover,help,nodead][help,nodead]神聖震擊 (有意義)
!宏技能名字前加感歎號，防止姿態被反覆按取消，如/cast !暗影形態，小德形態，消散冰箱等自帶取消功能的技能
/stopmacro [] 停止宏(括號裏要加條件，達到條件中斷這條命令以下的宏內)
比如“/stopmacro [mod:alt/ctrl]”按了alt或ctrl就不執行後面內容，“/stopmacro [nocombat]”沒有戰鬥，“/stopmacro [harm,nodead]”敵方存活，諸如此類
“/stopmacro [@mouseover,noexists] [@mouseover,dead] ”指向不存在或指向死亡不執行後面內容
*注意：這些條件也可以加在技能上反向判定，是專門用停止宏加條件還是直接加在技能上面得看哪一種總字符用得少比如“/stopmacro [mod]”和“/施放 [nomod]XX”是一個功能，如果後者重複使用過多就超過停止宏字符，設計一個總開關更節約字符
設置焦點(stopmacro停止宏進行下面命令，鼠標指向通過的條件)
/focus
/stopmacro [@mouseover,noexists] [@mouseover,dead]
/focus mouseover
/targetenemy 目標敵人(跟TAB一個機制，選正前方90度最遠50碼由近至遠輪流流選目標，只會選視野能看到的目標，不會選遮擋的目標，所有角度內目標選完了重複此過程，DOT職業有用)
/targetlasttarget 返回上一目標(一直返回在兩個目標間循環，配合上面的目標或配合指定XXX目標用，實現不切目標，像上面的例子)
/targetlastenemy 返回上一目標並鎖定(不會一直返回，鎖定最後一個目標)
/stopcasting 停止施法 (反制冰箱無敵之類需要立即放出來的技能)
/stopcasting [nochanneling:神聖讚美詩](不打斷[]內指定技能，一般用於引導類技能，比如讚美詩苦修眼稜等)
/stopattack 停止自動攻擊
*變形/癱瘓類軟控制指會被傷害打破的完全失去控制的技能，包括盲悶鑿閃懺羊慰等，這類技能施放成功會自動停止攻擊不需要額外加入命令
*注意癱瘓類道具如手雷不會自動停止攻擊
/startattack 自動攻擊(選擇最近目標並鎖定用武器近戰攻擊)
*技能類型和效果：技能類型分打擊技能和法術技能，技能效果分物理和魔法，例如DK窒息是法術技能物理效果會被保護免疫，DH邪能爆發是法術技能魔法效果會被反魔法護盾免疫，ZS風暴之錘是打擊技能物理效果，QS裁決是打擊技能魔法效果，QS妨害是法術技能魔法效果等等
*注意：1.打擊技能會優先開啟自動攻擊/startattack 選擇最近的目標並鎖定後才會嘗試施放技能，法術技能不會開啟自動攻擊，所有近戰的打斷包括DK和DH的遠程打斷是打擊技能不是法術技能，所有法系打斷是法術技能(懷舊服獵人射擊技能會開啟自動射擊，射擊技能和自動射擊不會自動選最近怪鎖定)
2.控制技能例如DK窒息DH邪能爆發是法術技能不會開啟自動攻擊，ZS風暴之錘是打擊技能會開啟自動攻擊，邪能爆發和風暴之錘都是遠程控制技能且都有傷害但是類別卻不同跟是否有傷害無關
3.法術技能(和懷舊服獵人射擊技能)前是否需要加入/startattack來協助選擇目標或是後續接普攻(法系捅圖騰，偷傷害)減少損失有細微的作用
/startattack [nostealth](潛行中禁止普攻，這個條件對賊德潛行起手技能加常規技能的組合宏很有必要)
懷舊服魔杖射擊，指向優先(秒圖騰!)
/施放 [@mouseover,harm,nodead][]!射擊
/petattack 寵物攻擊(寵物攻擊命令)
組合鍵寵物攻擊焦點敵人>寵物攻擊指向敵人>寵物攻擊目標敵人
/petattack [mod,@focus,harm][@mouseover,harm,nodead];
懷舊服沒焦點，其他同上
/petattack [@mouseover,harm,nodead];
/petstay 寵物停留(留在原地，並非停止攻擊，行為和姿態有關)
/petfollow 寵物跟隨(停止行為回到指定地點>跟着你)
/petmoveto 寵物移動(寵物移動到鼠標指定位置;正式服功能)
/petassist 寵物協助(是姿態;同你一起攻擊;正式服功能)
/petpassive 寵物被動(是姿態;停止行為回到指定地點>跟着你，什麼都不做)
/click PetActionButtonX (是腳本，字符佔用太多僅列出不推薦;點擊寵物動作條第X位置，X改成對應的位置)
/dismount 下坐騎
/f 名字(跟隨名字)
你可以在這些命令後面加[]目標條件或按鍵條件，比如按組合鍵寶寶跟隨“/petfollow [mod]”，目標是敵人下坐騎“/dismount [harm]”
/cleartarget (清除目標，一般配合選擇目標懷舊服刷怪用，下例不選中非敵人和死亡)
/目標 名字
/cleartarget [help][dead]
/施放 技能
/cancelform 取消變形(戰士小德懷舊服暗牧專用，加條件例如/cancelform [form:2/4]取消2和4形態)
/cancelaura 取消BUFF(例如/cancelaura 寒冰屏障)
[]括號，添加判定條件，狀態，敵友，焦點，指向，按鍵等(例如/cancelaura [mod]寒冰屏障，按組合鍵取消)
[nochanneling:苦修] 不中斷指定引導技能，不添加技能名字[nochanneling]會取消所有引導技能
例子盾不打斷苦修：/施放 [nochanneling:苦修]真言術：盾
*適用於奧術飛彈，術士吸取，獵人治療，死亡射線等引導技能或道具
姿態判定form
例1：不在姿態就進入姿態
#showtooltip
/startattack
/施放 [noform:1]暗影形態;[mod,@focus,harm][@mouseover,harm,nodead][]吸血鬼之觸
例2：按指定組合鍵不在該變形就變形>在形態就衝鋒指向>無指向衝目標
#showtooltip [@mouseover,exists,nodead][]野性衝鋒
/施放 [mod:alt,noform:1]熊形態;[mod:shift,noform:2]獵豹形態;[mod:ctrl,noform:4]梟獸形態;[@mouseover,exists,nodead][]野性衝鋒
換裝備指令
/eq(eq是equip的縮寫)和/equipslot(無法縮寫)
/eq 裝備名字，把裝備穿在默認的位置，類似右鍵穿戴
/equipslot 欄位編號(空格)裝備名字，指定穿戴，適用戒指飾品2個欄位
全身編號：1頭，2項鍊，3肩，4襯衣，5胸，6腰帶，7腿，8腳，9手腕，10手套，11戒指1，12戒指2，13飾品1，14飾品2，15披風，16主手，17副手
例：/eq 協同披風 /equipslot 13 驚惡角鬥士的咒徽
一切“script(腳本)”和“run(運行)”英文都應用中文“腳本”代替節約1-4個字符(腳本包含運行含義)
例如下面書寫格式有script也有run，很混亂
/script VehicleExit() 下載具，比如炮，座位載具
/run PetDismiss() 解散寵物
全部統一用中文“腳本”替換
/腳本 VehicleExit()
/腳本 PetDismiss()
常用遊戲設定命令，聊天框輸入命令運行，0是關閉，1是開啟
(/console是控制枱命令，聊天框輸入且重登無效時，需用文本打開WTF手動添加)
/console SET overrideArchive "0" 反和諧(除了圖標)
/console SET profanityFilter "0" 關文字過濾
/console SET ffxGlow "0" 關泛光效果(關閉光線反射會使色彩變暗，建議不關)
/console SET ffxDeath "0" 關死亡效果，黑白變彩色
/console SET weatherDensity "0" 天氣效果0-3檔由弱變強(降低暴雨，風沙，霧氣)
/console SET chatClassColorOverride "0" 聊天框顯示職業顏色
/console SET targetNearestDistance "50" 改TAB距離0-50碼
/console SET targetNearestDistanceRadius "50" 改TAB身後距離0-50碼，默認是10碼
敵方血條顯示命令
/腳本 SetCVar("nameplateShowEnemyGuardians",0) 守護者
/腳本 SetCVar("nameplateShowEnemyMinions",0) 僕從
/腳本 SetCVar("nameplateShowEnemyPets",0) 寵物
/腳本 SetCVar("nameplateShowEnemyTotems",0) 圖騰
/run SetCVar("nameplateShowEnemyMinus",0) 次要
友方血條顯示命令
/腳本 SetCVar("nameplateShowFriendlyGuardians",0) 守護者
/腳本 SetCVar("nameplateShowFriendlyMinions",0) 僕從
/腳本 SetCVar("nameplateShowFriendlyNPCs",0) NPC
/腳本 SetCVar("nameplateShowFriendlyPets",0) 寵物
/腳本 SetCVar("nameplateShowFriendlyTotems",0) 圖騰
鏡頭距離最高2.6自行調試
/腳本 SetCVar('cameraDistanceMaxZoomFactor', 2.6)
姓名板大字體姓名取代血條
/腳本 SetCVar("nameplateShowOnlyNames",0)
非當前目標血條透明度，尾數自改
/腳本 SetCVar("nameplateMinAlpha",0.7)
重置服務器設定(慎用!疑難雜症無解時的最後辦法)
/console cvar_default
以上收錄常見問題需要用到的功能，因為插件會修改設定，並不會還原，所以經常會遇見這類問題
迴歸本文主要講常規宏，順便收錄一些實用的LUA命令
#showtooltip 顯示圖標提示
#show 顯示圖標(不會顯示使用説明，除非字符不夠才用這個)
在後面加入天賦判斷命令[talent:x/x]，目標判斷命令[nopet]召喚寶寶;[pet]寶寶技能，加入指向判定等等能顯示距離判定超出距離會變紅
下面舉例描述如何做到距離顯示，焦點和指向的距離顯示，自動切換天賦技能，
重點：暴雪默認的技能超出距離圖標變紅作用於當前目標和按下焦點和指向施法鍵的時候;在加入技能名字固定顯示後只有當前目標生效，焦點和指向的距離判斷無效了，所以只有在邏輯上通過不了必須加才能監視的情況下加
這個技能不需要距離顯示，因為飾品序列在前面所以加了技能才能監視
#showtooltip 絕望禱言
/use 13
/施放 絕望禱言
/施放 [@player] 真言術：盾
/施放 [@player] 聖言術：靜
石像鬼是需要距離顯示的，因為飾品序列在前面所以加了技能和判斷條件才能監視，不過這類持續傷害技能生效期開飾品也一樣，可以把飾品放在最後簡化字符
#showtooltip [talent:7/2]邪惡狂亂;[mod,@focus,harm][@mouseover,harm,nodead][]召喚石像鬼
/use 13
/startattack
/施放 邪惡狂亂
/施放 [mod,@focus,harm][@mouseover,harm,nodead][]召喚石像鬼
簡化之後
#showtooltip
/startattack
/施放 [talent:7/2]邪惡狂亂
/施放 [mod,@focus,harm][@mouseover,harm,nodead][]召喚石像鬼
/use 13
2個不會同時點的天賦，給一個技能的三種施放條件(焦點，指向，目標)用[talent:x/x]排除法更簡約字符
組合鍵焦點友方>指向友方>目標友方
#showtooltip
/施放 [talent:5/2,mod,@focus,help,nodead][talent:5/2,@mouseover,help,nodead][talent:5/2]聯結治療;[mod,@focus,help,nodead][@mouseover,help,nodead][]治療之環
同上
組合鍵焦點敵方>指向敵方>目標敵方
#showtooltip
/startattack
/施放 [talent:3/3,mod,@focus,harm][talent:3/3,@mouseover,harm,nodead][talent:3/3]黑暗虛空;[mod,@focus,harm][@mouseover,harm,nodead][]虛空洪流
由於主要監視技能在最後面#showtooltip要想顯示野性衝鋒的距離判定，需要把他的施放條件(指向，目標)也加進來
按指定組合鍵不在該變形就變形>在形態就衝鋒指向>無指向衝目標
#showtooltip [@mouseover,exists,nodead][]野性衝鋒
/施放 [mod:alt,noform:1]熊形態;[mod:shift,noform:2]獵豹形態;[mod:ctrl,noform:4]梟獸形態;[@mouseover,exists,nodead][]野性衝鋒
上面介紹完宏的基礎，下面是一些運用案例，需要強調一句，寫宏不要死搬硬套，注意從上往下從左往右的語句邏輯，可以節約很多字符，可能你不去節約255字符也不會爆炸，但是應該把他當成創作去追求完美，養成良好的邏輯習慣去簡化語句，不要拖泥帶水藏污納垢
一個一元宏和一個多元宏他們的判斷條件都是完整的，但多元宏根據隊列邏輯可以使用排除法越往後選擇越少也就不需要條件了
三個組合鍵shift,ctrl,alt，如果三個都用上的情況那最後一個因排除法是不需要註明哪個鍵的，而最後一個必定是shift因為他5個字符;
舉個例子
/施放 [mod:alt]魔甲術;[mod:ctrl]奧術光輝;[mod]奧術智慧;冰甲術
/施放 [pet]黑暗突變;亡者復生(沒寶寶招寶寶，有寶寶變身)
/施放 [combat]狂暴姿態;戰鬥姿態(戰鬥中切換狂暴姿態，非戰鬥戰鬥姿態，懷舊服)
利用好敵友判定可以把1個宏做3+個技能外加3個組合鍵，X種條件進去，節約鍵位，高度智能，例子是6個判定3個組合鍵：
#showtooltip
/施放 [mod:alt,@targettarget,harm,nodead][@mouseover,harm,nodead][harm,nodead]驅散魔法;[mod:ctrl]羣體復活; [@mouseover,help,dead] [help,dead]復活術;[mod,@player][@mouseover,help,nodead][]純淨術
智能按環境上下坐騎自動拾取上BUFF，寶寶跟隨，停止攻擊，取消變形
附近有拾取優先拾取(拾取可以改成上BUFF，想同時存在其中一個要改成組合鍵)，組合鍵清包包修理三人坐騎>飛行坐騎=水下坐騎>陸地坐騎
#showtooltip 坐騎名字
/腳本 VehicleExit()
/dismount
/petfollow
/stopattack
/cancelform
/施放 玩具
/施放 遠程拾取器
/sp 小寵物
/施放 [mod]雄壯遠足犛牛;[swimming]水下坐騎;[flyable]飛行坐騎;陸地坐騎
智能飾品：地板光標，組合鍵焦點>鼠標指向>當前目標
#showtooltip
/施放 [mod,@focus,exists,nodead][@mouseover,exists,nodead] [@cursor] []13
正式服組合鍵切換飾品+智能施放
#showtooltip
/eq [mod:atl]飾品1;[mod:ctrl]飾品2;[mod]飾品3
/施放 [mod,@focus,exists,nodead][@mouseover,exists,nodead] [@cursor] []13
懷舊服組合鍵切換飾品+智能施放
/eq [mod:atl]飾品1;[mod:ctrl]飾品2;[mod]飾品3
/use [@mouseover,exists,nodead] [@cursor] []13
*注意：懷舊服裝備欄位數字編號使用物品需要用/use，直接用物品名字才可以用/施放，懷舊服沒有焦點
手雷或物品指向優先，組合鍵焦點施放，再次按打斷手雷施法重新施放
#showtooltip
/startattack
/stopcasting
/施放 [mod,@focus,exists,nodead][@mouseover,exists,nodead] [@cursor] []鐵皮手雷
懷舊服去除焦點，加入寵物跟隨，停止攻擊，取消變形
#showtooltip
/petfollow
/startattack
/stopattack
/cancelform
/stopcasting
/施放 [@mouseover,exists,nodead] [@cursor] []鐵皮手雷
吃喝用上藥五合一宏
#showtooltip
/施放 [mod:atl]食物BUFF;[mod:shift]職業BUFF;[mod:ctrl]敲鼓卷軸;[combat]藥;魔法漢堡
/腳本 BuyMerchantItem(12,180)
這個宏是購買180個NPC第12個位置(也就是第二頁第一行右邊)的東西
沒寶寶召喚寶寶，有寶寶放技能(指向技能可加命令)，同時寶寶攻擊
#showtooltip
/startattack
/施放 [nopet]招寶寶;[mod,@player] [@cursor] 水寶寶冰環
/petattack [mod,@focus,harm][@mouseover,harm,nodead];
DK版由於寶寶有2個技能，可以2個宏搭配
1沒寶寶招寶寶，有寶寶黑暗突變
#showtooltip
/startattack
/施放 [pet]黑暗突變;亡者復生
/petattack [mod,@focus,harm][@mouseover,harm,nodead];
2大於5碼寶寶衝鋒，小於5碼寶寶暈
#showtooltip
/startattack
/施放 [mod,@focus,harm][@mouseover,harm,nodead][]撕扯
/施放 [mod,@focus,harm][@mouseover,harm,nodead][]跳躍
/petattack [mod,@focus,harm][@mouseover,harm,nodead];
DKSS抓寵物解散寵物，在坐騎上就下坐騎解散
#showtooltip
/dismount
/startattack
/腳本 PetDismiss()
/施放 [mod,@focus,harm][@mouseover,harm,nodead][]控制亡靈
佔用一個格子的天賦變換宏，用[talent:X/X]命令，可以跨天賦組合
#showtooltip
/施放 [talent:1/3,@mouseover,harm,nodead][talent:1/3]暗影之爪
;[@mouseover,harm,nodead][]死疽打擊
一格組合鍵兩技
/施放 [mod,@mouseover]寶寶暈; [@mouseover] 自己暈
焦點目標的目標施法
/施放 [mod,@focustarget,harm,nodead][@mouseover,harm,nodead][]技能
施法隊列
/castsequence 是施法隊列宏
後邊接技能隊列
/castsequence reset=10/target/combat 技能1,技能2,技能3
reset部分是重置條件,走完隊列重置,放技能10秒閒置後重置(讀條技能是按開始讀條時計算),切目標重置,脱離戰鬥重置
例1：ctrl羣活，alt驅自己，shift驅焦點>指向敵人隊列打人，友方驅散，死亡復活>目標敵人隊列打人，友方驅散，死亡復活
#showtooltip
/castsequence [@mouseover,harm,nodead]reset=5 審判,十字軍打擊,十字軍打擊
/施放 [mod:ctrl]寬恕; [@mouseover,help,dead] [help,dead]救贖;[mod:alt,@player][mod,@focus,help,nodead][@mouseover,help,nodead][]清潔術
例2：組合鍵指向月火>組合鍵目標月火>指向隊列施法>目標隊列施法;換目標，脱戰，5秒閒置重置
#showtooltip
/startattack
/施放 [mod,@mouseover,harm,nodead][mod]月火術
/castsequence [@mouseover,harm,nodead][]reset=5/target/combat 斜掠,月火術
例3：隊列烈焰風暴類地板技能，組合鍵自己腳下>鼠標位置>鼠標指向>目標;5秒閒置重置
/castsequence [mod,@player] [@cursor] [@mouseover,harm,nodead][]reset=5 技能1,技能2,技能3
德魯伊同層天賦，組合鍵變形>某個天賦(如在施法打斷施法，需連按2次施放)
#showtooltip
/stopcasting
/施放 [talent:2/1]猛虎衝刺;[talent:2/2]甘霖;[mod:ctrl,nostance:1]熊形態;[mod:alt,nostance:3]旅行形態;[@mouseover,harm,nodead][]野性衝鋒
shift焦點友方，ctrl指向敵方>ctrl目標敵方>指向友方>目標友方>鎖定自己(避免失誤用於敵方)
#showtooltip
/施放 [mod:shift,@focus,help,nodead][mod:ctrl,@mouseover,harm,nodead][mod:ctrl,harm,nodead][@mouseover,help,nodead][help,nodead] [@player] 神聖震擊
治療輸出敵方判定，防止打斷引導
#showtooltip
/施放 [@targettarget,harm,nodead,nochanneling][harm,nodead,nochanneling]懲擊
治療目標和自身
#showtooltip
/施放 [mod,@player][@mouseover,help,nodead][]暗影癒合
牧師5判定驅和解(復活+羣活也做進來，節省2個偏遠鍵位)
治療例子：shift驅散目標的敵人，ctrl羣體復活，alt驅自己>指向敵方驅散，指向友方純淨，指向死亡友方復活>目標敵方驅散，目標友方驅散，目標友方死亡復活
#showtooltip
/施放 [mod:shift,@targettarget,harm,nodead][@mouseover,harm,nodead][harm,nodead]驅散魔法;[mod:ctrl]羣體復活; [@mouseover,help,dead] [help,dead]復活術;[mod,@player][@mouseover,help,nodead][]純淨術
輸出例子：暗牧推薦(解與驅的鍵位是高級別反應的，這個寶貴的鍵位應該更智能化，由於PVP驅散疾病不如薩滿驅散妖術有意義，但PVE又需要用到，使用率很低又不想佔位，驅散仍然可用，主要友方指向改成信仰飛躍，拯救被炸飛的隊友是關鍵)
alt驅指向友方，ctrl復活(對釋放屍體用)，shift拉焦點的友方目標>指向敵方驅散，指向友方拉人，指向友方復活>目標敵方驅散，目標友方拉人，目標友方死亡復活
#showtooltip
/施放 [mod:alt,@mouseover,help,nodead]淨化疾病;[mod:ctrl] [@mouseover,help,dead] [help,dead]復活術;[@mouseover,harm,nodead][harm,nodead]驅散魔法;[mod,@focustarget,help,nodead][@mouseover,help,nodead][]信仰飛躍
一些示範，需要注意隊列邏輯順序，同樣可用條件下優先執行前面的
例如：鼠標指向友方驅散=友方死亡復活>組合鍵打斷焦點>指向敵方打斷>目標打斷
如果同時指向友方按組合鍵是不能打斷焦點的，即隊列邏輯順序
#showtooltip
/施放 [mod:alt,@player][@mouseover,help,nodead][help,nodead]清毒術;[mod:ctrl] [@mouseover,help,dead] [help,dead]救贖;[mod,@focus,harm][@mouseover,harm,nodead][]責難
可以改隊列邏輯順序，修改優先順序或添加額外判定，比如脱戰判定nocombat通過才施放復活，下例就優先焦點了，除了多用字符外實戰中沒必要，因為好的宏是會避開衝突點的減少判斷需要的條件從而簡化字符
#showtooltip
/施放 [mod:shift,@focus,harm]責難;[mod:alt,@player][@mouseover,help,nodead][help,nodead]清毒術;[mod] [@mouseover,help,dead] [help,dead]救贖;[@mouseover,harm,nodead][]責難
組合鍵，指向，當前友方，當前敵方
#showtooltip
/施放 [mod,@player,nochanneling][@mouseover,help,nodead,nochanneling][help,nodead,nochanneling]真言術：耀;[harm,nodead,nochanneling]淨化邪惡
指向友方>目標友方換血，插戰旗，吃糖;組合鍵焦點敵方>指向敵方>目標敵方沉默
#showtooltip
/施放 [mod:ctrl][@mouseover,help,nodead][help,nodead]虛空轉移;[mod,@focus,harm][@mouseover,harm,nodead][]沉默
/施放 [@mouseover,help] [help]部落軍旗
/施放 [@mouseover,help] [help]治療石
按1下取消劍刃風暴>組合鍵戰鬥怒吼>鼠標指向打斷，同時指向用別的技能>目標打斷，同時目標用別的技能>距離不夠指向衝鋒>距離不夠目標衝鋒(疑問：盾牌猛擊必須在斬殺前面才能生效。多一個“/施放”比多2個“[spec:X]”節省9個字符)
#showtooltip
/cancelaura 劍刃風暴
/施放 [mod]戰鬥怒吼; [@mouseover,help,dead] [help,dead]終極版侏儒軍刀;[@mouseover,harm,nodead][]拳擊
/施放 [@mouseover,harm,nodead][]盾牌猛擊
/施放 [@mouseover,harm,nodead][]斬殺
/施放 [@mouseover,exists,nodead][]衝鋒
ctrl看復活CD，對目標復活;組合鍵敵方打斷>指向友方死亡戰鬥中戰復，非戰鬥電擊;指向敵方打斷>目標友方死亡戰鬥中戰復，非戰鬥電擊;目標敵方打斷
#showtooltip
/施放 [mod:ctrl][@mouseover,help,dead,combat][help,dead,combat]復活盟友; [@mouseover,help,dead] [help,dead]終極版侏儒軍刀;[mod,@focus,harm][@mouseover,harm,nodead][]心靈冰凍
DH滑翔速度固定178%，理論上DH在PVP應一直按空格，在某些不衝突的技能綁定“/施放 !滑翔”，!防止取消滑翔形態，綁定宏能增加移動速度加成的覆蓋率，比不停按空格3次才能觸發滑翔效率，保護雙手
PVP和PVE不同時點技能的整合宏，組合鍵自己腳下技能>光標處技能=指向伊利丹之握>目標伊利丹之握(伊利丹之握2段施放，1斷和常規指向或目標技能一樣，2段和地板技能一樣)
#showtooltip
/startattack
/施放 [talent:5/3,mod,@player][talent:5/3,@cursor]鎖鏈咒符;[@mouseover,harm,nodead][mod,@player] [@cursor] []伊利丹之握
DH刃舞和烈焰符咒隨天賦自動切換
*DH這2個不同專精的技能比較特殊，他們是共通的會自動切換可用的就像用了[spec:X]命令來實現切換;只有名稱是刃舞時烈焰咒符才會生效
#showtooltip 刃舞
/startattack
/施放 [mod,@player] [@cursor,nochanneling] 刃舞
DH衝刺和大跳隨專精自動切換
*DH這2個不同專精的技能比較特殊，他們是共通的會自動切換可用的就像用了[spec:X]命令來實現切換;只有名稱是邪能衝撞時地獄火撞擊才會生效
#showtooltip
/startattack
/施放 [mod,@player] [@cursor] 邪能衝撞
DH混亂打擊和靈魂裂劈隨專精自動切換;添加防打斷引導
*DH這2個不同專精的技能比較特殊，他們是共通的會自動切換可用的就像用了[spec:X]命令來實現切換;只有名稱是混亂打擊時靈魂裂劈才會生效
#showtooltip
/施放 [@mouseover,harm,nodead,nochanneling][nochanneling]混亂打擊
*DH專精共通技能另外還有疾影和嘲諷
三個不會同時點的天賦之間自動切換
#showtooltip
/startattack
/施放 [talent:3/3,mod,@focus,harm][talent:3/3,@mouseover,harm,nodead][talent:3/3]邪能之刃;[talent:6/2]幽魂炸彈;邪能毀滅
獵人招寶寶>寵物協同>殺戮命令
#showtooltip
/startattack
/petfollow (脱戰後被動可能會停在原地，跟隨是複寫被動命令;另外在無目標時作為單獨使用會跟隨你)
/petpassive (寶寶被動，停止行為>等待指令，習慣用協助可以改/petassist 在這個宏裏沒有區別，看你習慣常駐什麼姿態)
/petattack [mod,@focus,harm][@mouseover,harm,nodead];
/施放 [nopet]召喚寵物;[mod,@focus,harm][@mouseover,harm,nodead][]殺戮命令
(下面一些功能可能用不上，其他職業修改一下取長補短，配合釣魚,傳送,某技能宏簡化日常生活，加入宏終止避免換裝或釣魚同時放技能引到怪)
整合宏：組合鍵換武器>戰鬥復活>脱戰復活;某技能焦點>指向>目標
#showtooltip
/eq [mod:alt]武器名字
/stopmacro [mod:alt]
/施放 [mod:ctrl][@mouseover,help,dead,combat][help,dead,combat]復活盟友; [@mouseover,help,dead] [help,dead]終極版侏儒軍刀;[mod,@focus,harm][@mouseover,harm,nodead][]心靈冰凍
整合宏：組合鍵換魚竿，釣魚，傳送魚點;某技能焦點>指向>目標
#showtooltip
/eq [mod:alt]幽光魚竿
/施放 [mod:alt]釣魚;[mod:ctrl]暗流
/stopmacro [mod:alt/ctrl]
/startattack
/施放 [mod,@focus,harm][@mouseover,harm,nodead][]寒冰鎖鏈
示範2：如果不需要組合鍵焦點施法或不需要傳送魚點，即可全整合在一起
組合鍵換魚竿，武器，傳送魚點;某技能指向>目標
#showtooltip
/eq [mod:alt]幽光魚竿
/eq [mod:shift]武器名字
/施放 [mod:alt]釣魚;[mod:ctrl]暗流
/stopmacro [mod]
/startattack
/施放 [@mouseover,harm,nodead][]技能
復活密語提醒
#showtooltip
/施放 [@mouseover,help] []技能
/腳本 SendChatMessage("%T 密語內容","whisper",GetDefaultLanguage("target"),UnitName("target"))
戰士T,DHT,熊自動檔
組合鍵只放盾牌猛擊優先指向>直接按盾牌猛擊，能量=>40優先同時無視痛苦，能量=>30,40<同時格擋
#showtooltip
/施放 [mod,@mouseover,harm,nodead][mod]盾牌猛擊;[@mouseover,harm,nodead][]盾牌猛擊
/施放 [nomod]無視苦痛
/施放 [nomod]盾牌格擋
點評：邏輯優化後接近手動質量，盾牌格惡魔尖刺這類有層數的技能，雖然2次施放持續疊加不會溢出，但是兩次連續施放後面CD會有壓力，適合點強力反擊天賦避免自動檔的問題(戰士一般能延長2-3秒即33-50%時間，類似DH點減尖刺CD)，無視痛苦是刷新無法疊加，在敵方未攻擊的時候用組合鍵存能量(實驗證明優先無視痛苦可以讓盾擋真空期更分散避免沒點強力反擊天賦因連續施放盾擋導致真空期過大)
三系基礎技能自動切換整合版，其他功能同上
#showtooltip
/施放 [spec:1,@mouseover,harm,nodead][spec:1]致死打擊;[spec:2,@mouseover,harm,nodead][spec:2]嗜血;[mod,@mouseover,harm,nodead][mod]盾牌猛擊;[@mouseover,harm,nodead][]盾牌猛擊
/施放 [nomod]無視苦痛
/施放 [nomod]盾牌格擋
脱戰指向陷阱，戰鬥中指向陷阱同時假死
點評:指向冰凍陷才能瞬發，才能和後面的假死同時施放
/施放 [mod,@player] [@cursor] 冰凍陷阱
/stopmacro [nocombat]
/施放 假死
應簡化為
/施放 [mod,@player] [@cursor] 冰凍陷阱
/施放 [combat]假死
按順序施法，焦點>鼠標指向>目標的目標>寶寶>目標
#showtooltip
/施放 [@focus,help] [@mouseover,help,nodead] [@targettarget,help] [@pet,exists] []技能
指定隊友施法(只能是隊伍或團隊中的玩家)
#showtooltip
/施放 [@她的名字] 技能
目標宏，僅選中活生生的敵方目標
/目標 名字
/cleartarget [noharm][dead]
沒寶寶召喚寶寶，同時按寶寶技能欄5
點評：和前面法師水元素DK食屍鬼不同，加入寶寶鍵位欄指定按鍵可以配合獵人召喚不同寶寶的對應技能，比添加多個技能名好在能顯示正常
#showtooltip
/施放 [nopet]召喚寶寶
/click PetActionButton5
秒消BUFF，戰場秒丟旗幟，巫妖解控制，無盡犧牲控血，秒保護解狀態，各種飛行狀態
/cancelaura 巫妖之軀
/cancelaura 犧牲祝福
/cancelaura 保護祝福
/cancelaura 聖盾術
/cancelaura 寒冰屏障
/cancelaura 地精滑翔器
/cancelaura 降落傘
/cancelaura 緩落術
/cancelaura 漂浮術
/cancelaura 聯盟旗幟
/cancelaura 部落旗幟
/cancelaura 聯盟礦車
/cancelaura 部落礦車
/cancelaura 虛空風暴旗幟
一大堆我在用的宏，數次更新迭代，頭腦風暴的成果
戰士
自動專精，自動天賦，自動飾品
#showtooltip
/startattack
/施放 [spec:1,talent:6/2]致命平靜;天神下凡
/use [mod,@focus,exists,nodead][@mouseover,exists,nodead] [@cursor] []13
自動劍刃破壞者，自動飾品
#showtooltip
/cancelaura [mod]劍刃風暴
/施放 [mod,@player] [@cursor] 劍刃風暴
/use [mod,@focus,exists,nodead][@mouseover,exists,nodead] [@cursor] []13
騎士
shift焦點友方，ctrl鼠標指向>目標敵方，鼠標指向>目標友方，目標非友方自己
#showtooltip
/施放 [mod:shift,@focus,help,nodead][mod:ctrl,@mouseover,harm,nodead][mod:ctrl,harm,nodead][@mouseover,help,nodead][help,nodead] [@player] 神聖震擊
牧師
三選一
#showtooltip
/施放 [talent:6/2]神聖之星;[talent:6/3]光暈;[mod:shift,@focus,help,nodead][@mouseover,help,nodead][]神聖守衞
二連
#showtooltip
/castsequence reset=15 神聖之星,治療之環
懷舊服宏
補充技能的運用，還是和正式服一樣追求多功能智能化，精益求精的語法。
基礎內容建議先看主貼，懷舊服和和正式服語法完全一樣，此貼僅作為懷舊服技能運用的補充。
和正式服不同
正式服;施放近戰攻擊技能(例如致死打擊，旋風斬)會選擇目標>同時自動攻擊>同時施放技能(例如/startattack寫在技能前面一樣效果)
懷舊服;施放近戰攻擊技能不會選擇目標，只有在有資源施放時才會自動攻擊>同時施放技能
和懷舊服相同
普攻和技能同時施放，普攻在技能前生效，也可能是懷舊服200毫秒反饋判定造成和正式服相同的假象
強調這個不同意在宏的近戰攻擊技能前需要加入/startattack，有無資源施放都會自動攻擊
懷舊服一些額外説明
起手技能一般需要同時綁定起立，下坐騎命令
起立(坐下情況放技能第一次是起立，綁定這個命令按第一次就能放出技能)
/stand
下坐騎(騎馬狀態需要先下坐騎才能施放技能，綁定這個命令按第一次是下馬)
/dismount
小德變形普攻CD會按百分比延續，不會重新計時
換武器會重新計時普攻CD
戰鬥中換武器會有1.5秒GCD
招架使你本次近戰攻擊總量間隔降低40%(剩餘不足40%會立刻普攻，怪物也是)，可以理解為1%招架=1%閃避+0.4%攻速X怪物數量，戰騎T戰鬥賊招架收益最大。
聖騎士傷害聖印會觸發擊中時XX的附魔，
滿級1W經驗=6G，奧山交牌子=5G
第一個例子囉嗦一點，以後的例子都遵循這種精簡語法
小德全形態精靈之火，自動取消旅行形態
#showtooltip
/startattack
/cancelform [form:2/4]
/施放 [noform]精靈之火;精靈之火(野性)
#showtooltip
/startattack
/cancelform [form:2/4]
/施放 [noform,@mouseover,harm,nodead][noform]精靈之火;[@mouseover,harm,nodead][]精靈之火(野性)
[noform]沒形態即人形態，比起[form:1/3]鎖定為1熊或3豹形態要節約2字符
如果你有鼠標指向要求的話像主貼正式服的宏加入鼠標判定
如果你只要基礎功能的簡化宏也可以自行添加或取消這些額外的判定，以後的內容請自行加減，多個版本不一一舉例，選最多功能，智能化，最精簡的語法為初衷的版本
小德境界馬戲團雜技，變形大師
技能整合宏，精簡宏的數量，節約宏欄位
一般用於不同形態下才能使用的不同的需要做宏添加判定的技能
例如爪擊or揮擊因為需要用到/startattack自動攻擊而做了宏，這樣會佔用2個欄位，把他們整合在一起就只有一個欄位
(自動攻擊註釋：用近戰技能會自動選目標，沒資源的時候也會選目標，只在放出來的時候才會開啟自動攻擊，特別是用怒氣職業建議常用技能添加自動攻擊，以便無怒氣施放技能的時候也會開啟自動攻擊平砍)
#showtooltip
/startattack
/施放 [form:3]爪擊;揮擊
進階：為了立馬擊殺掉薩滿的圖騰，做了瞬發技能的指向宏，當你鼠標划過去就瞬間秒掉了圖騰，從而節約選定的操作，這種簡化在德的技能上尤其明顯，比如戰士在旋風斬或順批的時候旁邊目標閃避了，你可以划過去用一鍵切換姿態帶指向功能的壓制宏對閃避目標壓制
(貓賊會丟豆子建議手動，下面只改了熊揮擊)
#showtooltip
/startattack
/施放 [form:3]爪擊;[@mouseover,harm,nodead][]揮擊
/startattack自動攻擊命令的使用：用近戰技能會自動選擇最近的目標(跟TAB一樣，僅選擇)，近戰技能施放成功的同時會開啟自動攻擊。建議怒氣職業常用技能添加自動攻擊，以便無怒氣施放技能的時候也會開啟自動攻擊平砍。潛行技能在找面向時會多次嘗試施放，不要添加自動攻擊避免破潛行
小德取消其他形態同時變形>潛行>技能，組合鍵取消潛行
#showtooltip
/cancelaura [mod]潛行
/cancelform [form:1/2/4]
/施放 [noform:3]獵豹形態;[nostealth]潛行;毀滅
小德取消其他形態同時變形同時潛行>技能，組合鍵取消潛行
#showtooltip
/cancelaura [mod]潛行
/cancelform [form:1/2/4]
/施放 [noform:3]獵豹形態
/施放 [nostealth]潛行;毀滅
整合有GCD和無GCD技能一鍵施放簡化操作
無GCD技能：部分打斷，衝鋒攔截，變形姿態，影遁賊德潛行
有GCD和無GCD技能的組合一鍵完成簡化操作;
比如切之態同時衝鋒並自動判定戰鬥中切狂暴攔截，防禦姿態同時盾擊，小德變形同時潛行，這些操作都只需要一鍵
德整合1：潛行>潛行技能>普通技能，組合鍵取消潛行，爪機和揮擊整合
#showtooltip
/cancelaura [mod]潛行
/施放 [form:3,nocombat,nostealth]潛行;[form:3,stealth]毀滅;[form:3]爪擊;[@mouseover,harm,nodead][]揮擊
德整合2-1(四鍵)：.取消其他形態同時變形>潛行>潛行技能>普通技能，組合鍵取消潛行
#showtooltip
/cancelaura [mod]潛行
/cancelform [form:1/2/4]
/施放 [noform:3]獵豹形態;[nocombat,nostealth]潛行;[stealth]毀滅;撕碎
德整合2-2(三鍵).取消其他形態同時變形同時潛行>潛行技能>普通技能，ctrl或alt取消潛行
*變形作為起手技能加入額外的下坐騎，起立
*增加shift覆蓋變形;加入此開關把宏當作常規變形減少重複功能節省鍵位，點了激怒覆蓋變形刷能量;另秒解定身減速
#showtooltip
/stand
/dismount
/cancelaura [mod]潛行
/cancelform [mod:shift][form:1/2/4]
/施放 [noform:3]獵豹形態
/stopmacro [mod]
/施放 [nocombat,nostealth]潛行;[stealth]毀滅;撕碎
一鍵衝鋒(德)：取消其他形態同時變熊同時衝鋒(自動攻擊在變形之後，如果沒有CD可以增加怒氣)
*變形作為起手技能加入額外的下坐騎，起立
*增加組合鍵覆蓋變形;加入此開關把宏當作常規變形減少重複功能節省鍵位，避免點了激怒天賦變形有資源導致同時誤放技能;另秒解定身減速
#showtooltip [@mouseover,harm,nodead][]野性衝鋒
/stand
/dismount
/cancelform [mod][form:2/3/4]
/施放 [noform:1]巨熊形態
/startattack
/stopmacro [mod]
/施放 [@mouseover,harm,nodead][]野性衝鋒
一鍵重擊：取消其他形態同時變熊同時重擊(自動攻擊在變形之後，如果沒有CD可以增加怒氣)
*變形作為起手技能加入額外的下坐騎，起立
*增加組合鍵覆蓋變形;加入此開關把宏當作常規變形減少重複功能節省鍵位，避免點了激怒天賦變形有資源導致同時誤放技能;另秒解定身減速
#showtooltip [@mouseover,harm,nodead][]重擊
/stand
/dismount
/cancelform [mod][form:2/3/4]
/施放 [noform:1]巨熊形態
/startattack
/stopmacro [mod]
/施放 [@mouseover,harm,nodead][]重擊
盜賊境界審時度勢，致命一擊
盜賊脱戰潛行+換匕首，潛行偷竊+伏擊(或偷襲)，戰鬥切割(或背刺)+換劍錘
*潛行作為起手技能加入額外的下坐騎，起立
三鍵版
潛行+換匕首>偷竊+伏擊>切割+換劍錘，組合鍵取消潛行
#showtooltip [nocombat,nostealth]潛行;[stealth]伏擊;切割
/stand
/dismount
/cancelaura [mod]潛行
/施放 搜索
/stopcasting
/施放 [nocombat,nostealth]潛行;[stealth]伏擊;切割
/equipslot [stealth]16 匕首名字
/equipslot [nostealth]16 劍錘名字
二鍵版
潛行+換匕首>偷竊+伏擊+換劍錘，組合鍵取消潛行
#showtooltip [nocombat,nostealth]潛行;伏擊
/stand
/dismount
/cancelaura [mod]潛行
/施放 搜索
/stopcasting
/施放 [nocombat,nostealth]潛行;伏擊
/equipslot 16 匕首名字
/equipslot 16 劍錘名字
盜賊還擊+邪惡+投擲(弓弩槍)+換武器
換武器放在技能前需要按2次影響手感，為了避免第一次傷害由匕首造成所以換武器由上面的潛行宏完成，這裏加入作為檢查保險
#showtooltip 邪惡攻擊
/startattack
/施放 還擊
/施放 邪惡攻擊
/施放 投擲
/equipslot 16 劍錘名字
鑿擊，悶棍，致盲，懺悔，諸如此類技能的偷刀宏(放技能時你的普攻沒CD就能偷一刀，原理是傷害在效果之前產生不會打破控制。此類技能施放成功本就會停止攻擊，加上/stopattack停止攻擊防止因連按再次自動攻擊，在下次普攻CD就緒之前都不會因連按而攻擊)
#showtooltip
/startattack
/stopattack
/施放 [@mouseover,harm,nodead][]致盲
地板技能一鍵施法：按shtft腳下>按ctrl或alt鼠標瞄準後點擊>鼠標瞄點位置(地板類技能通用，烈焰風暴，冰火箭雨，照明彈，手雷)
#showtooltip
/startattack
/施放 [mod:shift,@player][mod] [@cursor] 手雷
獵人境界人寵合一，活用陷阱
添加!防止覆按取消自動射擊，所有包含自動射擊的宏都應加!
*自動射擊也會隨着技能施放自動打開，包括超出距離未能施放成功的近戰技能，技能必須是就緒能施放狀態才會自動打開
/施放 !自動射擊
指向多重，自動射擊，寶寶攻擊>目標多重，自動射擊，寶寶攻擊;綁定猛禽
*技能沒好也會自動射擊，鼠標指向點圖騰，近戰施放猛禽，獵人遠近攻擊不共CD，保持指向對遠處目標攻擊同時對近身目標近戰攻擊，利用這個命令最大化資源節省切目標操作量;可如法炮製其他技能，控寵命令不宜過多使用導致其跑在路上
#showtooltip [@mouseover,harm,nodead][]多重射擊
/施放 猛禽一擊
/startattack
/petattack [@mouseover,harm,nodead];
/施放 [@mouseover,harm,nodead][]!自動射擊
/施放 [@mouseover,harm,nodead][]多重射擊
*獵人的近戰和射擊不是共CD，就是説獵人的最高DPS是保持遠近攻擊的CD，添加這個命令的宏不用來回切目標節省操作量，或者臨時射點什麼，但是誰會去記這些奇怪的條件還熟練運用呢?
/施放 [@mouseover,harm,nodead][]!自動射擊
獵人自動守護：隊伍脱戰豹羣>單人脱戰獵豹>戰鬥雄鷹;組合鍵靈猴，野獸(!防止取消)
#showtooltip
/startattack
/施放 [mod:alt]!靈猴守護;[mod]!野獸守護;[combat]!雄鷹守護;[group]!豹羣守護;!獵豹守護
獵人主動守護：獵豹雄鷹切換;組合鍵靈猴，野獸，豹羣
#showtooltip
/startattack
/施放 [mod:alt]!靈猴守護;[mod:ctrl]!野獸守護;[mod]!豹羣守護
/castsequence 獵豹守護,雄鷹守護
獵人一鍵召喚餵養，所有寵物類型和相應食物
#showtooltip
/stand
/dismount
/施放 [pet]餵養寵物;召喚寵物
/use [pet:豹/狼/迅猛龍]烤鵪鶉;[pet:蝙蝠]風乾的香蕉;[pet:熊/猩猩/野豬/風蛇]魔法甜麪包
死了復活，沒有屍體按組合鍵復活>活着解散>沒有召喚;跟隨保持10碼解散範圍
#showtooltip
/petfollow
/startattack
/施放 [mod] [@pet,dead] 復活寵物;[pet]解散野獸;召喚寵物
四合一究極寵物宏(前兩個宏的整合)：死了復活，沒有屍體按ctrl復活>按shift餵養>活着解散>沒有召喚
#showtooltip
/stand
/dismount
/petfollow
/startattack
/施放 [mod:ctrl] [@pet,dead] 復活寵物;[mod:shift]餵養寵物;[pet]解散野獸;召喚寵物
/stopmacro [mod:ctrl]
/施放 [pet:豹/狼/迅猛龍]烤鵪鶉;[pet:蝙蝠]風乾的香蕉;[pet:熊/猩猩/野豬/風蛇]魔法甜麪包
*“/stopmacro [mod:ctrl]”按ctrl停止下面內容，下面內容是餵食功能的下半部分按類型選擇食物，如果沒有按shift施放餵養技能而下半部分選擇食物依然生效會出現食物被自己吃了的情況，所以用終止命令來區分開
*如果條件單一應該單獨加入“mod:shift”條件而不使用終止宏，實際像這樣“[mod:shift,pet:豹/狼/迅猛龍]烤鵪鶉”和上面的shift餵養技能同步運行，但由於這個宏的種類判定有三個需要加三個“mod:shift,”就達到了30字符，不如終止宏“/stopmacro [mod:ctrl]”21個字符簡約且能匹配下面的無限種類擴展
治療寵物，組合鍵低級治療解DEBUFF;防止中斷引導
#showtooltip
/startattack
/施放 [mod,nochanneling:治療寵物]治療寵物(等級 1);[nochanneling:治療寵物]治療寵物
天眼查
#showtooltip
/stand
/dismount
/施放 [@cursor] !鷹眼術
戰鬥假死>影遁陷阱，脱戰影遁陷阱，組合鍵其他影遁陷阱
#showtooltip
/petfollow
/施放 [combat]假死
/施放 [mod:alt]冰霜陷阱;[mod:ctrl]獻祭陷阱;[mod]爆炸陷阱;冰凍陷阱
/施放 !影遁
/施放 !潛伏
點評：寵物存活情況假死後主人脱戰寵物還在戰鬥，宏判定寶寶還在戰鬥所不能用判定脱戰來施放陷阱，只能另起一行同時施放陷阱
戰士境界武器大師，三系戰神
一鍵衝鋒or攔截，1.姿態圖標版無法監視技能圖標CD和距離：切戰鬥姿態衝鋒>戰鬥中切狂暴攔截
這個版本顯示的姿態圖標，切換姿態後才顯示技能，因為同時施放的緣故，基本看不到顯示技能的情況，這樣就失去了監視技能圖標CD和超出距離變紅的功能
#showtooltip
/施放 [combat]狂暴姿態;戰鬥姿態
/startattack
/施放 [combat,@mouseover,harm,nodead][combat]攔截;[@mouseover,harm,nodead][]衝鋒
一鍵衝鋒or攔截，2.技能圖標版監視技能CD和距離：功能同上，區別在有圖標距離顯示，起手技能應添加起立下馬命令
這個版本脱戰顯示衝鋒，戰鬥攔截，指向和目標都有距離判定
#showtooltip [combat,@mouseover,harm,nodead][combat]攔截;[@mouseover,harm,nodead][]衝鋒
/stand
/dismount
/施放 [combat]狂暴姿態;戰鬥姿態
/startattack
/施放 [combat,@mouseover,harm,nodead][combat]攔截;[@mouseover,harm,nodead][]衝鋒
戰神：顧名思義，三合一自動切姿態換武器化身為神，可惜你只能選擇其中之一而且只有10秒鐘真男人萎靡一整天
*可以用作一鍵切換劍盾和防禦姿態，坐騎上可以切換武器和姿態，加入自動攻擊會導致下坐騎，已是劍盾會嘗試施放技能也會下坐騎;這個附屬功能是方便坐騎上變得更硬方便衝破障礙方便趕路
#showtooltip [mod:alt]反擊風暴;[mod]魯莽;盾牆
/施放 [mod:alt]戰鬥姿態;[mod]狂暴姿態;防禦姿態
/equip [mod]雙手武器
/equipslot [nomod]16 單手武器
/equip [nomod]盾牌名字
/施放 [mod:alt]反擊風暴;[mod]魯莽;盾牆
一鍵盾擊：狂暴切防禦，戰鬥同時盾擊;如需換武器連按2次施放技能
#showtooltip [@mouseover,harm,nodead][]盾擊
/施放 [form:3]防禦姿態
/startattack
/equipslot 16 單手武器
/equip 盾牌名字
/施放 血性狂暴
/施放 [@mouseover,harm,nodead][]盾擊
一鍵繳械：切防禦同時繳械
#showtooltip [@mouseover,harm,nodead][]繳械
/施放 防禦姿態
/startattack
/施放 血性狂暴
/施放 [@mouseover,harm,nodead][]繳械
一鍵拳擊：切狂暴同時拳擊
#showtooltip [@mouseover,harm,nodead][]拳擊
/施放 狂暴姿態
/startattack
/施放 血性狂暴
/施放 [@mouseover,harm,nodead][]拳擊
一鍵旋風：切狂暴同時旋風斬;如需換武器連按2次施放技能
#showtooltip 旋風斬
/施放 狂暴姿態
/equip 雙手武器
/startattack
/施放 旋風斬
一鍵壓制：戰鬥直接壓制，防禦狂暴切武器同時壓制;如需換武器連按2次施放技能
#showtooltip [@mouseover,harm,nodead][]壓制
/施放 戰鬥姿態
/equip 雙手武器
/startattack
/施放 [@mouseover,harm,nodead][]壓制
一鍵斷筋：武器直接斷筋，防禦切狂暴同時斷筋
#showtooltip [@mouseover,harm,nodead][]斷筋
/施放 [form:2]狂暴姿態
/startattack
/施放 [@mouseover,harm,nodead][]斷筋
一鍵斬殺：戰鬥直接斬殺，防禦切狂暴同時壓制;默認換武器
#showtooltip [@mouseover,harm,nodead][]斬殺
/施放 [form:2]狂暴姿態
/equip 雙手武器
/startattack
/施放 [@mouseover,harm,nodead][]斬殺
一鍵橫掃：切姿態同時普攻同時血性狂暴同時橫掃(普攻就緒時才能一鍵施放，依靠普攻的怒氣同時橫掃，普攻CD時需要按2次，因為血性狂暴返還的怒氣有延遲)
#showtooltip 橫掃攻擊
/施放 戰鬥姿態
/equip 旋風之斧
/startattack
/施放 血性狂暴
/施放 橫掃攻擊
注意1：戰士和熊一樣自動攻擊加怒氣，應該在切換姿態之後才自動攻擊增加當前姿態的怒氣，保證不易出，也保證變熊或切姿態後當前姿態有額外的怒氣
舉例：如果你有25點怒氣切姿態旋風斬，你也正好普攻沒有CD，切換姿態後普攻加了10點怒氣，旋風斬用掉25點，這時候你還剩10點，而不是先攻擊在隨着切姿態浪費掉，在PVE無間斷的普攻這個邏輯細節可能沒有用，不過PVP經常有打不到人普攻無CD的狀態是很有用的，養成良好的邏輯習慣
戰德還有很多可以做一鍵切姿態的技能，繳械，嘲諷，盾牆，懲戒痛擊，狂暴之怒，精靈之火，諸如此類等等，如法炮製
注意2：戰士的姿態不會取消，德魯伊的形態重複按會取消變人，他們涉及姿態或形態的宏有一定差異
比如戰士有拳擊，繳械這種指定單一姿態施放的技能只需要“/施放 XX姿態”即可，而盾擊，斷筋，斬殺這種雙姿態都能施放的技能要加入“/施放 [form：X]XX姿態”來判定，比如你在防禦姿態去按斷筋就會切到指定的戰鬥或狂暴之態施放
德魯伊的技能都是單形態施放，不像戰士有雙姿態能施放的技能，比如要變熊衝鋒第一行先取消別的形態“/cancelform [form:2/3/4]”取消234形態，第二行“/施放 [noform:1]巨熊形態”變熊，其中[noform:1]防止重複按鍵取消形態
布甲魔杖射擊指向目標，寶寶攻擊指向目標>射擊目標，寶寶攻擊目標
#showtooltip
/startattack
/petattack [@mouseover,harm,nodead];
/施放 [@mouseover,harm,nodead][]!射擊
牧師
友方優先指向驅散復活同時解除形態，組合鍵驅自己或復活(對釋放屍體用);敵方優先指向沉默
#showtooltip
/stopcasting [@mouseover,harm] [harm]
/cancelform [mod] [@mouseover,help] [help]
/施放 [mod:alt,@player][@mouseover,help,nodead][help,nodead]驅除疾病;[mod] [@mouseover,help,dead] [help,dead]復活術;[@mouseover,harm,nodead][]沉默
優先指向驅散，組合鍵驅自己
#showtooltip
/施放 [mod,@player][@mouseover,exists,nodead][]驅散魔法
不打斷鞭子引導
#showtooltip [@mouseover,harm,nodead][]精神鞭笞
/startattack
/施放 [@mouseover,harm,nodead,nochanneling:精神鞭笞][nochanneling:精神鞭笞]精神鞭笞
加入!防止誤觸取消形態，取消!在施放暗影形態1.5秒後能直接按下取消形態;按組合鍵取消形態
PS：起立同時暗影形態，坐騎上可以取消形態遂取消了下坐騎命令
#showtooltip
/stand
/startattack
/cancelform [mod]
/施放 暗影形態
組合鍵1級痛>鼠標指向>目標(1級追殺刷暈，眾所周知暗牧沒法留人)
#showtooltip
/stand
/dismount
/startattack
/施放 [mod,@mouseover,help,nodead][mod]暗言術：痛(等級 1);[@mouseover,help,nodead][]暗言術：痛
騎士
友方優先指向復活驅散，組合鍵復活(對釋放屍體用)或驅自己
#showtooltip
/施放 [mod:shift] [@mouseover,help,dead] [help,dead]救贖;[mod,@player][@mouseover,help,nodead][]清潔術
懺悔優先指向
#showtooltip
/startattack
/stopattack
/施放 [@mouseover,harm,nodead][]懺悔
法師，解詛咒和反制+?
法師
組合鍵1級寒冰>鼠標指向>目標(1級1-1.5秒讀條快速減速)
#showtooltip
/startattack
/施放 [mod,@mouseover,harm,nodead][mod]寒冰箭(等級 1);[@mouseover,harm,nodead][]寒冰箭
不打斷暴風雪引導：按shtft鼠標瞄點位置1級雪>按ctrl或alt鼠標瞄準後點擊>鼠標瞄點位置
#showtooltip 暴風雪
/startattack
/施放 [mod:shift,@cursor]暴風雪(等級 1);[mod][@cursor,nochanneling:暴風雪]暴風雪
小德，解中毒和戰復+纏繞，解詛咒和休眠+安撫
騎士，解淨化和復活+?
隊列施放，優先指向，5秒重置
#showtooltip
/dismount
/stand
/startattack
/castsequence [@mouseover,harm,nodead][]reset=5 獻祭,痛苦詛咒,腐蝕術
各職業整合宏
組合鍵適用整合頻率不高的非反應類型技能道具，通常shift,alt比ctrl好按一些，自己有設置組合鍵習慣的可以去掉相應的按鍵避免衝突，盜賊4種毒左右鍵點擊八合一，能起到整合作用又不影響操作情況就算二合一也有意義
作為思維擴展包含很多各職業各種族延伸功能，一點思路請自行調節，不需要的功能請自行加減
宏能實現30個以上的功能整合在一個鍵位嗎?受限於255字符可以用宏擴展插件突破，但這樣做違背宏簡化操作的根本，也無法監視圖標的狀態：3個組合鍵+正常鍵，姿態，敵我，死亡，戰鬥，環境等判定以4的倍數擴展，3個組合鍵+正常鍵的左右鍵分別點擊，已經突破30個技能判定了。做宏要打牢基礎，不忘初衷，千萬不要掉入華而不實的陷阱，思維可以延伸，但要切合實際
上毒藥四合一，左鍵主手右鍵副手
#showtooltip
/施放 [mod:alt]致命藥膏; [mod:ctrl]麻痺毒藥;[mod]致殘毒藥;速效毒藥
/use [button:1]16; [button:2]17
法師BUFF四合一
#showtooltip
/施放 [mod:alt]魔甲術;[mod:ctrl]奧術光輝;[mod]奧術智慧;冰甲術
傳送三合一
#showtooltip
/施放 [mod:alt]傳送：暴風城;[mod]傳送：達納蘇斯;傳送：鐵爐堡
專業四合一
#showtooltip
/施放 [mod:alt]烹飪;[mod:ctrl]急救;[mod]工程學;鍊金術
吃喝用上藥五合一;整合取消形態，影遁，潛行，寶寶潛行
#showtooltip
/cancelform
/施放 [mod:alt]用道具;[mod:ctrl]吃烹飪;[mod]上BUFF;[combat]藥;吃食物
/stopmacro [mod:shift/ctrl]
/施放 [combat]XX治療石
/施放 喝水
/施放 影遁
/施放 潛行
/施放 !潛伏
全職業版(除暗牧)，其他功能同上，加入鼠標指向上BUFF，鼠標右鍵吃藍藥，取消寒冰屏障
#showtooltip
/cancelform
/cancelaura 寒冰屏障
/施放 [mod:ctrl]吃烹飪;[mod:shift,@mouseover,help,nodead][mod:shift]上BUFF;[button:2]XX法力藥水;[combat]XX治療藥水;吃食物
/stopmacro [mod:shift][button:2]
/施放 [combat]XX治療石
/施放 喝水
/施放 影遁
/施放 潛行
/施放 !潛伏
盜賊版(BUFF欄改毒藥)
#showtooltip
/施放 [mod:ctrl]吃烹飪;[mod:shift]毒藥;[combat]XX治療藥水;吃食物
/stopmacro [mod:shift]
/施放 [combat]XX治療石
/施放 影遁
/施放 潛行
暗牧版(不取消形態)
#showtooltip
/施放 [mod:ctrl]吃烹飪;[mod:shift,@mouseover,help,nodead][mod:shift]真言術：韌;[button:2]XX法力藥水;[combat]XX治療藥水;吃食物
/stopmacro [mod:shift][button:2]
/施放 [combat]XX治療石
/施放 喝水
/施放 影遁
全職業(除暗牧)上坐騎整合宏：同時起立，下馬，停止攻擊，寶寶跟隨，寵物潛行;組合鍵種族技能
小德額外功能：戰鬥取消變形同時變水棲或旅行，秒切姿態解定身減速;小寵物
按ctrl或alt取消形態同時影遁，按shift取消形態變形旅行形態，用於脱戰短距離旅行
#showtooltip
/stand
/dismount
/petfollow
/stopattack
/cancelform [combat][nocombat]
/施放 精龍的蛋(需要小動物添加這一行在坐騎前面，小德添加在取消形態下面變形前面)
/施放 [swimming]水棲形態;[mod:shift][combat]旅行形態
/施放 [mod]感知;黑馬韁繩
/施放 [mod]!影遁;條紋霜刃豹韁繩
/施放 [mod]!潛伏
/施放 召喚地獄戰馬
/施放 召喚軍馬
單職業的話在上面基礎上修改，小德和暗牧形態衝突不能共存需單獨做一個
小德：取消形態同時變水棲或旅行，秒切姿態解定身減速;
按ctrl取消形態同時影遁，按shift或alt取消形態同時上坐騎
#showtooltip
/stand
/dismount
/cancelform [combat][nocombat]
/施放 [mod:ctrl]!影遁;[mod]條紋霜刃豹韁繩;[swimming]水棲形態;旅行形態
暗牧：去掉取消形態
#showtooltip
/stand
/dismount
/stopattack
/施放 [mod]!影遁;條紋霜刃豹韁繩
/施放 [mod]感知;黑馬韁繩
全職業取消宏
/cancelform
/cancelaura 魔法抑制
/cancelaura 魔法增效
/cancelaura 法力護盾
一鍵標記宏(數字改人名)
/腳本 SR=SetRaidTarget;TG="target"
/cleartarget
/目標 1
/script SR(TG,1)
/cleartarget
/目標2
/script SR(TG,2)
/cleartarget
/目標3
/script SR(TG,3)
/cleartarget
/目標4
/script SR(TG,4)
/cleartarget
/目標5
/script SR(TG,5)
趣味遊戲館
